【コピペでOK】エクセルでフォルダ自動作成！VBAマクロでの一括作成方法！

決まった名前のファイルを毎回作るのが面倒…
大量のファイルを作って名前変更する作業が手間がかかる

社内ルール通りの名前で案件ごとにフォルダを作成したり、日付別のファイルを大量に作るような業務ってまだまだ残っていると思います。そんな時、1つずつ右クリックで作成するのって、面倒ですよね。

そんな悩みをで解決してくれるのが、VBAを使ったフォルダ自動作成の方法です。

今回紹介するVBAコードをコピペするだけで、エクセルに入力したリストからフォルダを一括で作成できます。初心者にもやさしいコードなので、業務効率化の第一歩としてもおすすめです！

また「VBAは初めてでよく分からない…」という方のために、完成済みエクセルファイルも用意しました。ダウンロードしてすぐ試すこともできるので、そちらもぜひ活用してみてください。

このブログでは、コピペで使えるVBAなど、効率化に関する情報を発信しています。この記事が参考になれば、ぜひほかの記事も見てみてください！

【結論】コピペで使えるフォルダ作成VBA
フォルダ自動作成VBAの動作
フォルダ自動作成VBAの使い方
さいごに

【結論】コピペで使えるフォルダ作成VBA

以下のVBAコードをそのままエクセルに貼り付ければ、セルの内容に従ってフォルダを一括で作成できます。

実行には、あらかじめ項目の作成が必要です。使い方の詳細は後ほど解説します。

Sub CreateFolders()
    Dim folderPath As String
    Dim ws As Worksheet
    Dim lastRow As Long
    Dim i As Long
    Dim parentFolder As String
    Dim subFolder As String
    Dim targetPath As String
    Dim fileDialog As Object

    ' フォルダ選択ダイアログを表示
    Set fileDialog = Application.fileDialog(msoFileDialogFolderPicker)
    fileDialog.Title = "CSVファイルが入っているフォルダを選択してください"
    If fileDialog.Show = -1 Then
        folderPath = fileDialog.SelectedItems(1) ' 選択したフォルダパスを取得
    Else
        MsgBox "フォルダが選択されていません。処理を中止します。"
        Exit Sub
    End If

    Set ws = ActiveSheet ' アクティブシートを使用
    lastRow = ws.Cells(ws.Rows.Count, "A").End(xlUp).Row

    For i = 2 To lastRow
        parentFolder = ws.Cells(i, 1).Value
        subFolder = ws.Cells(i, 2).Value

        ' 親フォルダ作成
        If Len(parentFolder) > 0 Then
            If Dir(folderPath & "\" & parentFolder, vbDirectory) = "" Then
                MkDir folderPath & "\" & parentFolder
            End If

            ' サブフォルダ作成（B列に値がある場合）
            If Len(subFolder) > 0 Then
                targetPath = folderPath & "\" & parentFolder & "\" & subFolder
                If Dir(targetPath, vbDirectory) = "" Then
                    MkDir targetPath
                End If
            End If
        End If
    Next i

    MsgBox "フォルダの作成が完了しました。"
End Sub