【コピペでOK】VBAでフォルダ内エクセルを一括統合！コピペで使えるコード紹介！

Inuiwan

1週間前

エクセルのデータを統合したいけど、いちいち開けるのは面倒
沢山あるエクセルのどこに必要なデータがあるかわからない…

たくさんあるエクセルを一つずつ開けて確認する手間がかかりますよね。溜まってしまうと、ほしいデータを見つけるだけで、かなりの時間がかかってしまいます。

そんな時に便利なのが、今回紹介するエクセル統合VBAです。このVBAでは、フォルダに入っているエクセルファイルを一つのエクセルにまとめることができます。これにより検索性が格段に向上します。さらに、目次作成VBAを使用することで、一覧を作成しより見やすいファイルが作成できます。

この記事ではVBAが使えない人でもわかるように、コピペで使えるコードを使って環境設定から紹介しています。ぜひこの記事を参考に、VBAの効率化を行ってみてください。

【結論】コピペで使えるエクセル統合VBA
エクセル統合VBAの動作
エクセル統合VBAの使い方
まとめ

【結論】コピペで使えるエクセル統合VBA

以下のコードをコピペするだけで、指定したフォルダ内のエクセルファイルを一つに統合できます。

各エクセルのシートを一つのエクセルのシートに追加して統合が可能です。

Sub ImportXLSXFilesToExcel()
    Dim folderPath As String
    Dim targetFile As String
    Dim wb As Workbook      ' 統合先（新規）ブック
    Dim targetBook As Workbook ' コピー元（各ファイル）ブック
    Dim ws As Worksheet     ' コピー元シート
    Dim fileDialog As Object

    ' 画面のチラつきを抑える設定
    Application.ScreenUpdating = False
    ' フォルダ選択ダイアログを表示
    Set fileDialog = Application.fileDialog(msoFileDialogFolderPicker)
    fileDialog.Title = "Excelファイル(xlsx)が入っているフォルダを選択してください"
    If fileDialog.Show = -1 Then
        folderPath = fileDialog.SelectedItems(1)
    Else
        MsgBox "フォルダが選択されていません。処理を中止します。"
        Exit Sub
    End If    
    ' 新しいワークブックを作成（ここに集約）
    Set wb = Workbooks.Add    
    ' フォルダ内のxlsxファイルを順番に処理
    targetFile = Dir(folderPath & "\*.xlsx")
    Do While targetFile <> ""
        ' 自身のファイル（マクロ実行中のファイル）や一時ファイルを除外する簡易チェック
        If targetFile <> ThisWorkbook.Name And Left(targetFile, 2) <> "~$" Then
            ' Excelファイルを開く
            Set targetBook = Workbooks.Open(folderPath & "\" & targetFile)        
            'そのブック内の「全てのシート」をループしてコピー
            For Each ws In targetBook.Worksheets
                ws.Copy After:=wb.Sheets(wb.Sheets.Count)
            Next ws
            ' コピー元ファイルを閉じる（保存しない）
            targetBook.Close False
        End If
        ' 次のファイルを取得
        targetFile = Dir
    Loop
    ' 初期シート（新規作成時にある空白シート「Sheet1」）を削除
    Application.DisplayAlerts = False
    If wb.Sheets.Count > 1 Then
        wb.Sheets(1).Delete
    End If
    Application.DisplayAlerts = True
    ' 設定を戻す
    Application.ScreenUpdating = True
    MsgBox "Excelファイルの全シート統合が完了しました！"
End Sub

※当サイトで紹介している他のコピペコードは、コチラにまとめています！